# $Id$
divert(-1)

# Mail configuration for dumb clients:
# Just forward all mail blindly to the central mail server and don't try
# to resolve aliases or locally deliver mail to local accounts.

# Make sure, that it relays local mail, only! To accomplish this, use 
# enable local delivery mode (i.e. sendmail's -bl option):
#	svccfg -s smtp:sendmail 'setprop config/local_only = true'

# To activate this file, do:
#	cp sendmail.mc /etc/mail/
#	svccfg -s smtp:sendmail \
#		'setprop config/path_to_sendmail_mc = "/etc/mail/sendmail.mc"'
#	svccfg -s smtp:sendmail 'setprop config/include_info = boolean: true'

# Finally refresh any SMF changes for this service and restart:
#	svccfg -s smtp:sendmail refresh
#	svcadm restart smtp:sendmail

# This should regenerate the /etc/mail/sendmail.cf every time the smtp:sendmail
# service gets restarted and the content of the sendmail.mc has been changed.
# Also it avoids, that OS updates overwrite the generated sendmail.cf file.
divert(0)
OSTYPE(solaris11)dnl
divert(-1)
# Like the nullclient feature, but without any masquerade.
# Define the name or IP of the central mail server where to forward all mail:
divert(0)
define(`_NULL_CLIENT_', `mail')
define(`STATUS_FILE',`/var/log/sendmail.st')
undefine(`ALIAS_FILE')
define(`MAIL_HUB', _NULL_CLIENT_)
define(`SMART_HOST', _NULL_CLIENT_)
define(`confFORWARD_PATH', `')
define(`confDONT_EXPAND_CNAMES', `True')
define(`_DEF_LOCAL_MAILER_FLAGS', `lsDFM5q')
dnl remove the 'dnl ' in the next line to listen/talk to IPv4 interfaces, only
dnl undefine(`_NETINET6_')
FEATURE(`nouucp',`reject')
FEATURE(`stickyhost')
FEATURE(`nocanonify')
FEATURE(`accept_unresolvable_domains')
MAILER(`local')
MAILER(`smtp')